{
  inputs,
  outputs,
  suiteModules,
  lib,
  config,
  pkgs,
  ...
}: {
  imports = [
    ./lauretta-hardware-configuration.nix
    inputs.nixos-hardware.nixosModules.lenovo-thinkpad-t480
    inputs.musnix.nixosModules.musnix
    inputs.home-manager.nixosModules.home-manager
    suiteModules.nixos.base
    suiteModules.nixos.exwm
    suiteModules.nixos.audio
    suiteModules.nixos.bluetooth
    suiteModules.nixos.steam
    suiteModules.nixos.virtualization
    suiteModules.nixos.binfmt
    suiteModules.nixos.attic
  ];

  boot.loader.systemd-boot.enable = true;
  boot.loader.efi.canTouchEfiVariables = true;

  nixpkgs = {
    overlays = [
      outputs.overlays.addpkgs
      outputs.overlays.qutebrowserdrm
      outputs.overlays.modifications
      outputs.overlays.unstable-packages
    ];
    config = {
      allowUnfree = true;
    };
  };

  nix.registry = (lib.mapAttrs (_: flake: {inherit flake;})) ((lib.filterAttrs (_: lib.isType "flake")) inputs);
  nix.nixPath = ["/etc/nix/path"];

  networking.hostName = "lauretta";
  networking.networkmanager.enable = true;

  time.timeZone = "Asia/Jerusalem";

  i18n.defaultLocale = "en_IL";
  i18n.extraLocaleSettings = {
    LC_ADDRESS = "he_IL.UTF-8";
    LC_IDENTIFICATION = "he_IL.UTF-8";
    LC_MEASUREMENT = "he_IL.UTF-8";
    LC_MONETARY = "he_IL.UTF-8";
    LC_NAME = "he_IL.UTF-8";
    LC_NUMERIC = "he_IL.UTF-8";
    LC_PAPER = "he_IL.UTF-8";
    LC_TELEPHONE = "he_IL.UTF-8";
    LC_TIME = "he_IL.UTF-8";
  };

  services.xserver = {
    xkb = {
      layout = "us,il";
      variant = "";
    };
    xkb.options = "grp:alt_shift_toggle";
  };

  console.keyMap = "il";

  users.users.aner = {
    isNormalUser = true;
    description = "Aner Zakobar";
    extraGroups = ["networkmanager" "wheel" "audio" "video"];
    packages = with pkgs; [];
  };

  nix.settings = {
    experimental-features = "nix-command flakes";
    auto-optimise-store = true;
  };

  azos.suites.exwm.enable = true;
  azos.attic.enable = true;

  home-manager = {
    extraSpecialArgs = {inherit inputs outputs suiteModules pkgs;};
    users = {
      aner = import ../home-manager/home.nix;
    };
  };

  specialisation = {
    hyprland = {
      configuration = {
        home-manager.users.aner = {pkgs, ...}: {
          azos.suites.exwm.enable = lib.mkForce false;
          azos.suites.hyprland.enable = true;
        };
      };
    };
  };

  boot.supportedFilesystems = ["exfat"];
  boot.kernelModules = ["exfat"];

  environment.systemPackages = with pkgs; [
    vim
    git
    tmux
    killall
    brightnessctl
    exfatprogs
  ];

  fonts.enableDefaultPackages = true;

  services.upower.enable = true;

  systemd.targets.sleep.enable = false;
  systemd.targets.suspend.enable = false;
  systemd.targets.hibernate.enable = false;
  systemd.targets.hybrid-sleep.enable = false;

  system.stateVersion = "25.11";
}